[XSL-LIST Mailing List Archive Home] [By Thread] [By Date] [Recent Entries] [Reply To This Message]

Re: General algorithm for finding nodes between PIs

Subject: Re: General algorithm for finding nodes between PIs
From: "Martin Honnen martin.honnen@xxxxxx" <xsl-list-service@xxxxxxxxxxxxxxxxxxxxxx>
Date: Thu, 26 Jan 2017 20:31:11 -0000
Re:  General algorithm for finding nodes between PIs
On 26.01.2017 20:53, Martin Honnen martin.honnen@xxxxxx wrote:
On 26.01.2017 20:45, Rick Quatro rick@xxxxxxxxxxxxxx wrote:

I have XML with a bunch of different processing instructions in them;
here
is a sample:

<?xml version="1.0" encoding="UTF-8"?>
<info>
    <?Fm Condstart VbV-VCO?>
    <p>For this, use <b>that </b>to do that.</p>
    <?Fm Condend VbV-VCO?>
    <p><?Fm Condstart USB?>If you need this, do that.<?Fm Condend
USB?></p>
</info>


For each "pair" of processing instructions (Condstart and Condend with the same string), I want to find all of the nodes between them.

Are the matching pairs always sibling nodes? Or can they be at different nesting levels?

In case of siblings it sounds like an easy job for for-each-group
group-starting-with="processing-instruction('Fm')"/for-each-group
group-ending-with.


Like this:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
exclude-result-prefixes="xs"
version="2.0">

<xsl:template match="/">
<results>
<xsl:apply-templates/>
</results>
</xsl:template>

<xsl:template match="*[processing-instruction('Fm')[starts-with(., 'Condstart')]]">
<xsl:for-each-group select="node()" group-starting-with="processing-instruction('Fm')[starts-with(., 'Condstart')]">
<xsl:if test="self::processing-instruction('Fm')[starts-with(., 'Condstart')]">
<group name="{.}">
<xsl:variable name="pi-end-name" select="replace(., 'Condstart', 'Condend')"/>
<xsl:for-each-group select="current-group() except ." group-ending-with="processing-instruction('Fm')[. = $pi-end-name]">
<xsl:if test="current-group()[last()][self::processing-instruction('Fm')[. = $pi-end-name]]">
<xsl:copy-of select="current-group()[position() ne last()]"/>
</xsl:if>
</xsl:for-each-group>
</group>
</xsl:if>
</xsl:for-each-group>
<xsl:apply-templates/>
</xsl:template>

<xsl:template match="text()"/>

</xsl:stylesheet>


Current Thread

PURCHASE STYLUS STUDIO ONLINE TODAY!

Purchasing Stylus Studio from our online shop is Easy, Secure and Value Priced!

Buy Stylus Studio Now

Download The World's Best XML IDE!

Accelerate XML development with our award-winning XML IDE - Download a free trial today!

Don't miss another message! Subscribe to this list today.
Email
First Name
Last Name
Company
Subscribe in XML format
RSS 2.0
Atom 0.3
Site Map | Privacy Policy | Terms of Use | Trademarks
Free Stylus Studio XML Training:
W3C Member
Stylus Studio® and DataDirect XQuery ™are products from DataDirect Technologies, is a registered trademark of Progress Software Corporation, in the U.S. and other countries. © 2004-2013 All Rights Reserved.