Re: Generating book index via attributes...

Play the video

Subject: Re: Generating book index via attributes...
From: Martin Honnen <Martin.Honnen@xxxxxx>
Date: Fri, 09 Apr 2010 19:54:57 +0200

Dave Carvell wrote:

(Using XMLSpy Enterprise Edition version 2010 rel. 2, xsl 1.0)

<?xml version="1.0" encoding="utf-8"?>
<docroot>
    <chapter>
        <title>
            Brakes
            <indxref refs1="Brakes"/>
        </title>
         <subchapter>
            <title>
                Drum type Brakes
                <indxref refs1="Brakes" refs2="drum"/>
            </title>
            <para>stuff...
                <indxref refs1="Brakes" refs2="drum" refs3="diagram"/>
       </para>
       ...

I need to generate an index. For now, I just need a hierarchical listing.

Maybe the following does what you want but I am guessing as to what you want to achieve:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">

<xsl:output method="html" indent="yes"/>

  <xsl:key name="refs1Key"
           match="indxref/@refs1"
           use="."/>

  <xsl:key name="refs2Key"
           match="indxref/@refs2"
           use="concat(../@refs1, '|', .)"/>

  <xsl:key name="refs3Key"
           match="indxref/@refs3"
           use="concat(../@refs1, '|', ../@refs2, '|', .)"/>

<xsl:template match="docroot"> <xsl:apply-templates select="//indxref/@refs1[generate-id() = generate-id(key('refs1Key', .)[1])]" mode="group"> <xsl:sort select="."/> </xsl:apply-templates> </xsl:template>

<xsl:template match="@refs1" mode="group"> <xsl:value-of select="."/> <br/> <xsl:apply-templates select="key('refs1Key', .)/../@refs2[generate-id() = generate-id(key('refs2Key', concat(../@refs1, '|', .))[1])]" mode="group"> <xsl:sort select="."/> </xsl:apply-templates> </xsl:template>

<xsl:template match="@refs2" mode="group"> <br/>....<xsl:value-of select="." /><br/> <xsl:apply-templates select="key('refs2Key', concat(../@refs1, '|', .))/../@refs3[generate-id() = generate-id(key('refs3Key', concat(../@refs1, '|', ../@refs2, '|', .))[1])]" mode="group"> <xsl:sort select="."/> </xsl:apply-templates> </xsl:template>

  <xsl:template match="@refs3" mode="group">
    <br/>........<xsl:value-of select="." /><br/>
  </xsl:template>

</xsl:stylesheet>

--

	Martin Honnen
	http://msmvps.com/blogs/martin_honnen/

Current Thread
Generating book index via attributes... Dave Carvell - 9 Apr 2010 17:15:54 -0000 Martin Honnen - 9 Apr 2010 17:30:15 -0000 Martin Honnen - 9 Apr 2010 17:55:26 -0000 <= <Possible follow-ups> Dave Carvell - 12 Apr 2010 12:36:02 -0000

<- Previous	Index	Next ->
Re: Generating book index via, Martin Honnen	Thread	Re: Generating book index via, Dave Carvell
Re: Generating book index via, Martin Honnen	Date	Re: Create Table, bernie bonn
	Month

PURCHASE STYLUS STUDIO ONLINE TODAY!

Purchasing Stylus Studio from our online shop is Easy, Secure and Value Priced!

Download The World's Best XML IDE!

Accelerate XML development with our award-winning XML IDE - Download a free trial today!

Subscribe in XML format

RSS 2.0
Atom 0.3

XML Editor - Download a 15 Day Free Trial Now >

See What's New in Stylus Studio >

Buy Stylus Studio - XML Editor - Now >