Re: Re: Grouping by attribute

Play the video

Subject: Re: Re: Grouping by attribute
From: Martin Honnen <Martin.Honnen@xxxxxx>
Date: Wed, 21 Oct 2009 15:04:08 +0200

Joo Lajos wrote:

<par class="Bullet 6" xml:lang="hu"> Valami szoveg <inline style="color: #ff0000;"> Sima inline </inline> szoveg <inline style="color: #ff0000;"> inline break elott. <linebreak/> inline break utan </inline> szoveg break elott <linebreak/> szoveg break utan <inline style="color: #ff0000;"> inline bold elott <bold> inline bold break elott <linebreak/> inline bold break utan </bold> inline bold utan </inline> Sima szoveg. </par> Indenting is not too pretty but it can be seen that there are linebreaks in <par> in <par><inline> and in <par><inline><bold> I need to break up this into :

<par class="Bullet 6" xml:lang="hu"> Valami szoveg <inline style="color: #ff0000;"> Sima inline </inline> szoveg <inline style="color: #ff0000;"> inline break elott. </inline> </par> <par class="Bullet 6" xml:lang="hu"> <inline style="color: #ff0000;"> inline break utan </inline> szoveg break elott </par> <par class="Bullet 6" xml:lang="hu"> szoveg break utan <inline style="color: #ff0000;"> inline bold elott <bold> inline bold break elott </bold> </inline> </par> <par class="Bullet 6" xml:lang="hu"> <inline style="color: #ff0000;"> <bold> inline bold break utan </bold> inline bold utan </inline> Sima szoveg. </par>

Here is an XSLT 2.0 stylesheet that produces the described output:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0"
  xmlns:xsd="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xsd">

<xsl:output indent="yes"/>

  <xsl:template match="@*">
    <xsl:copy/>
  </xsl:template>

  <xsl:template match="node()">
    <xsl:param name="cn"/>
    <xsl:if test="descendant-or-self::node() intersect $cn">
      <xsl:copy>
        <xsl:apply-templates select="@*, node()">
          <xsl:with-param name="cn" select="$cn"/>
        </xsl:apply-templates>
      </xsl:copy>
    </xsl:if>
  </xsl:template>

<xsl:template match="par"> <xsl:variable name="p" as="element()" select="."/> <xsl:for-each-group select="descendant::node()" group-ending-with="linebreak"> <xsl:variable name="lb" as="element()?" select="current-group()[self::linebreak]"/> <par> <xsl:apply-templates select="$p/@*"/> <xsl:apply-templates select="$p/node()[descendant-or-self::node() intersect (current-group() except $lb)]"> <xsl:with-param name="cn" select="current-group() except $lb"/> </xsl:apply-templates> </par> </xsl:for-each-group> </xsl:template>

</xsl:stylesheet>

--

	Martin Honnen
	http://msmvps.com/blogs/martin_honnen/

Current Thread
Re: Grouping by attribute Joo Lajos - 21 Oct 2009 12:25:11 -0000 Michael Kay - 21 Oct 2009 12:35:39 -0000 Martin Honnen - 21 Oct 2009 13:05:04 -0000 <= Lajos Joo - 21 Oct 2009 14:02:41 -0000 Martin Honnen - 21 Oct 2009 14:08:14 -0000 Lajos Joo - 21 Oct 2009 14:34:54 -0000 Martin Honnen - 21 Oct 2009 15:23:10 -0000

<- Previous	Index	Next ->
RE: Re: Grouping by attribute, Michael Kay	Thread	Re: Re: Grouping by attribute, Lajos Joo
Re: Filename encoding, Jesper Tverskov	Date	Re: Filename encoding, Syd Bauman
	Month

PURCHASE STYLUS STUDIO ONLINE TODAY!

Purchasing Stylus Studio from our online shop is Easy, Secure and Value Priced!

Download The World's Best XML IDE!

Accelerate XML development with our award-winning XML IDE - Download a free trial today!

Subscribe in XML format

RSS 2.0
Atom 0.3

XML Editor - Download a 15 Day Free Trial Now >

See What's New in Stylus Studio >

Buy Stylus Studio - XML Editor - Now >