XML Editor
Sign up for a WebBoard account Sign Up Keyword Search Search More Options... Options
Chat Rooms Chat Help Help News News Log in to WebBoard Log in Not Logged in
Show tree view Topic
Topic Page 1 2 3 4 5 6 7 8 9 Go to previous topicPrev TopicGo to next topicNext Topic
Postnext
Jeff HatchSubject: List item grouping in XSLT 2.0
Author: Jeff Hatch
Date: 03 Jun 2005 12:48 PM
Hello,

I have tried to get my arms around the new grouping features in XSLT 2.0, but am having some difficulty. Need to transform the following:

<chapter>
<head1>This is the Head 1</head1>
<para>This is paragraph content</para>
<para>This is paragraph content</para>
<para>This is paragraph content</para>
<head1>This is the head 1</head1>
<bulletListItem>• This is a bullet list item</bulletListItem>
<bulletListItem>• This is a bullet list item</bulletListItem>
<bulletListItem>• This is a bullet list item</bulletListItem>
<bulletListItem>• This is a bullet list item</bulletListItem>
<para>This is paragraph content</para>
<para>This is paragraph content</para>
<bulletListItem>• This is a bullet list item</bulletListItem>
<bulletListItem>• This is a bullet list item</bulletListItem>
<Head2>This is the head 2</Head2>
<numberListItem>1. This is a number list item</numberListItem>
<numberListItem>2. This is a number list item</numberListItem>
<numberListItem>3. This is a number list item</numberListItem>
<numberListItem>4. This is a number list item</numberListItem>
<numberListItem>5. This is a number list item</numberListItem>
</chapter>

To the following output/result:

<chapter>
<head1>This is the Head 1</head1>
<para>This is paragraph content</para>
<para>This is paragraph content</para>
<para>This is paragraph content</para>
<head1>This is the head 1</head1>
<bulletList>
<bulletListItem>• This is a bullet list item</bulletListItem>
<bulletListItem>• This is a bullet list item</bulletListItem>
<bulletListItem>• This is a bullet list item</bulletListItem>
<bulletListItem>• This is a bullet list item</bulletListItem>
</bulletList>
<para>This is paragraph content</para>
<para>This is paragraph content</para>
<bulletList>
<bulletListItem>• This is a bullet list item</bulletListItem>
<bulletListItem>• This is a bullet list item</bulletListItem>
</bulletList>
<Head2>This is the head 2</Head2>
<numberList>
<numberListItem>1. This is a number list item</numberListItem>
<numberListItem>2. This is a number list item</numberListItem>
<numberListItem>3. This is a number list item</numberListItem>
<numberListItem>4. This is a number list item</numberListItem>
<numberListItem>5. This is a number list item</numberListItem>
</numberList>
</chapter>

Any help would be greatly appreciated. Thanks ...

Postnext
Ivan PedruzziSubject: List item grouping in XSLT 2.0
Author: Ivan Pedruzzi
Date: 06 Jun 2005 08:15 AM
Hi Jeff,

The following method works for both XSLT versions

Hope this helps
Ivan Pedruzzi
Stylus Studio Team

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/">
<xsl:apply-templates/>
</xsl:template>

<xsl:template match="@* | node()">
<xsl:copy>
<xsl:apply-templates select="@* | node()"/>
</xsl:copy>
</xsl:template>

<xsl:template match="*" mode="body">
<xsl:copy-of select="."/>
<xsl:variable name="local" select="local-name()"/>
<xsl:apply-templates select="following-sibling::*[1][local-name() = $local]" mode="body"/>
</xsl:template>

<xsl:template match="bulletListItem">
<xsl:if test="local-name(preceding-sibling::*[1]) != 'bulletListItem'">
<bulletList>
<xsl:apply-templates select="." mode="body"/>
</bulletList>
</xsl:if>
</xsl:template>

<xsl:template match="numberListItem">
<xsl:if test="local-name(preceding-sibling::*[1]) != 'numberListItem'">
<numberList>
<xsl:apply-templates select="." mode="body"/>
</numberList>
</xsl:if>
</xsl:template>

</xsl:stylesheet>

Postnext
Jeff HatchSubject: List item grouping in XSLT 2.0
Author: Jeff Hatch
Date: 06 Jun 2005 10:43 AM
This was very helpful -- thank you. I'm still curious to know if this sort of grouping could be handled with the "for-each-group" process in 2.0. My attempts have failed, in that if I have two separate bulleted lists, my stylesheet grouped all list items together in the same single list. Anyone have any thoughts?

Posttop
Ivan PedruzziSubject: List item grouping in XSLT 2.0
Author: Ivan Pedruzzi
Date: 08 Jun 2005 01:57 AM

Here is a solution using for-each-group (XSLT 2.0)

Hope this helps
Ivan Pedruzzi
Stylus Studio Team


<?xml version="1.0"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>

<xsl:template match="/">
<xsl:apply-templates/>
</xsl:template>

<xsl:template match="@* | node()">
<xsl:copy>
<xsl:apply-templates select="@* | node()"/>
</xsl:copy>
</xsl:template>

<xsl:template match="chapter">
<xsl:copy>
<xsl:for-each-group select="*" group-adjacent="local-name()">
<xsl:choose>
<xsl:when test="current-grouping-key() = 'bulletListItem'">
<bulletList>
<xsl:copy-of select="current-group()"/>
</bulletList>
</xsl:when>
<xsl:when test="current-grouping-key() = 'numberListItem'">
<numberList>
<xsl:copy-of select="current-group()"/>
</numberList>
</xsl:when>
<xsl:otherwise>
<xsl:apply-templates select="current-group()"/>
</xsl:otherwise>
</xsl:choose>
</xsl:for-each-group>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>

 
Topic Page 1 2 3 4 5 6 7 8 9 Go to previous topicPrev TopicGo to next topicNext Topic
Download A Free Trial of Stylus Studio 6 XML Professional Edition Today! Powered by Stylus Studio, the world's leading XML IDE for XML, XSLT, XQuery, XML Schema, DTD, XPath, WSDL, XHTML, SQL/XML, and XML Mapping!  
go

Log In Options

Site Map | Privacy Policy | Terms of Use | Trademarks
Stylus Scoop XML Newsletter:
W3C Member
Stylus Studio® and DataDirect XQuery ™are from DataDirect Technologies, is a registered trademark of Progress Software Corporation, in the U.S. and other countries. © 2004-2016 All Rights Reserved.