SSDN - How to add a string with math operators ?

XML Editor

Sign Up

Search

Options

Chat

Help

News

Log in

Not Logged in

Topic

Topic Page 1 2 3 4 5 6 7 8 9

noor

Subject: How to add a string with math operators ?
Author: noor
Date: 10 Apr 2009 03:52 AM

Hi all,

May i know how to add a string with math operators ?

For example,

a variable has "30 + 40 + 10"
and i get the result as "80"

Please help me to get this...

John Bampton

Subject: How to add a string with math operators ?
Author: John Bampton
Date: 10 Apr 2009 06:52 AM

This xsl outputs the value 80 based on the input of '30 + 40 + 10'
just change the input string to get a different sum

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
exclude-result-prefixes="xs"
version="2.0">
<xsl:template match="/">
<xsl:variable name="string" select=" '30 + 40 + 10' "></xsl:variable>
<xsl:call-template name="sumstring">
<xsl:with-param name="string" select="$string"></xsl:with-param>
<xsl:with-param name="sum" select="0"></xsl:with-param>
</xsl:call-template>
</xsl:template>
<xsl:template name="sumstring">
<xsl:param name="string"></xsl:param>
<xsl:param name="sum"></xsl:param>
<xsl:choose>
<xsl:when test="string-length($string)">
<xsl:variable name="firstnumber" select="
if ( contains($string,'+') )
then number(substring-before($string,'+'))
else number($string) "></xsl:variable>

<xsl:variable name="currentsum" select="$sum + $firstnumber"></xsl:variable>

<xsl:variable name="newstring" select="if ( contains($string,'+') )
then substring-after($string,'+')
else '' "></xsl:variable>

<xsl:call-template name="sumstring">
<xsl:with-param name="string" select="$newstring"></xsl:with-param>
<xsl:with-param name="sum" select="$currentsum"></xsl:with-param>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$sum"></xsl:value-of>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>

Cheers, John Bampton.

noor

Subject: How to add a string with math operators ?
Author: noor
Date: 10 Apr 2009 09:06 AM

Very thanks to u Mr. john.

I has another question,

Can we achieve this (john's) approach in xsl version 1.0, rather than using xsl 2.0

So, i need to run it in xsl version 1.0 ?
please give me the solution ...

Tony Lavinio

Subject: How to add a string with math operators ?
Author: Tony Lavinio
Date: 10 Apr 2009 11:42 AM

There is no reason to continue two threads on this.
Please just reply to the first one.

John Bampton

Subject: How to add a string with math operators ?
Author: John Bampton
Date: 10 Apr 2009 12:37 PM

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
exclude-result-prefixes="xs"
version="1.0">
<xsl:template match="/">
<xsl:variable name="string" select=" '30 + 40 + 10' "></xsl:variable>
<xsl:call-template name="sumstring">
<xsl:with-param name="string" select="$string"></xsl:with-param>
<xsl:with-param name="sum" select="0"></xsl:with-param>
</xsl:call-template>
</xsl:template>
<xsl:template name="sumstring">
<xsl:param name="string"></xsl:param>
<xsl:param name="sum"></xsl:param>
<xsl:choose>
<xsl:when test="string-length($string)">
<xsl:variable name="firstnumber">
<xsl:choose>
<xsl:when test="contains($string,'+')">
<xsl:value-of select="number(substring-before($string,'+')) "></xsl:value-of>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="number($string)"></xsl:value-of>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:variable name="currentsum" select="$sum + $firstnumber"></xsl:variable>
<xsl:variable name="newstring">
<xsl:choose>
<xsl:when test="contains($string,'+')">
<xsl:value-of select="substring-after($string,'+')"></xsl:value-of>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="''"></xsl:value-of>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:call-template name="sumstring">
<xsl:with-param name="string" select="$newstring"></xsl:with-param>
<xsl:with-param name="sum" select="$currentsum"></xsl:with-param>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$sum"></xsl:value-of>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>

Cheers, John Bampton.

Topic Page 1 2 3 4 5 6 7 8 9

Powered by Stylus Studio, the world's leading XML IDE for XML, XSLT, XQuery, XML Schema, DTD, XPath, WSDL, XHTML, SQL/XML, and XML Mapping!

Go to Conference:

Log In Options Username: Password:

Site Map | Privacy Policy | Terms of Use | Trademarks

Stylus Studio® and DataDirect XQuery ™are from DataDirect Technologies, is a registered trademark of Progress Software Corporation, in the U.S. and other countries. © 2004-2016 All Rights Reserved.