[XSL-LIST Mailing List Archive Home] [By Thread] [By Date] [Recent Entries] [Reply To This Message]

json to json transformation

Subject: json to json transformation
From: "Mukul Gandhi gandhi.mukul@xxxxxxxxx" <xsl-list-service@xxxxxxxxxxxxxxxxxxxxxx>
Date: Fri, 15 Mar 2019 10:41:52 -0000
 json to json transformation
Hi all,
    XPath 3.1 has functions json-to-xml() and xml-to-json(). I thought of
using these two functions in a XSLT 3.0 stylesheet, to do json to json
transformations. Below is an example of this,

Input JSON file person.txt:

{
   "id" : 105,
   "medals" : [1, 2, 3],
   "fName" : "Mukul",
   "lName" : "Gandhi",
   "address" : {
      "street1" : "xyz",
      "street2" : "maddison avenue",
      "country" : "C1"
    }
}

I wish to transform above JSON document, into another JSON document which
should look like following,

{
   "id" : 105,
   "medals" : [1, 2, 3],
   "name" : "Mukul Gandhi",
   "address" : {
      "street1" : "xyz",
      "street2" : "maddison avenue",
      "country" : "C1"
    }
}

Everything in second JSON document is same as the first one, except that
"fName" and "lName" fields have been merged into one "name" field.
Following is a XSLT stylesheet I've written for the mentioned requirements,

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                         xmlns:xs="http://www.w3.org/2001/XMLSchema"
                         xmlns:fn="http://www.w3.org/2005/xpath-functions"
                         exclude-result-prefixes="xs fn"
                         version="3.0">

    <xsl:variable name="inpJson" select="unparsed-text('person.txt')"
as="xs:string"/>

    <xsl:output method="text" />

    <xsl:template match="/">
       <xsl:variable name="inpXml" select="json-to-xml($inpJson)"/>
       <xsl:variable name="intermediate">
          <xsl:apply-templates select="$inpXml/fn:map" mode="M0"/>
       </xsl:variable>
       <xsl:copy-of select="xml-to-json($intermediate, map{'indent':
true()})"/>
    </xsl:template>

    <xsl:template match="node() | @*" mode="M0">
        <xsl:copy>
            <xsl:apply-templates select="node() | @*" mode="M0"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="fn:string[@key = 'fName']" mode="M0">
       <fn:string key="name"><xsl:value-of select="concat(., ' ',
following-sibling::fn:string[1])"/></fn:string>
    </xsl:template>

    <xsl:template match="fn:string[@key = 'lName']" mode="M0"/>

</xsl:stylesheet>

The above mentioned stylesheet, produces the wanted results.

Just thought of sharing these facts with members here, for any comments,
suggestions.




-- 
Regards,
Mukul Gandhi

Current Thread

PURCHASE STYLUS STUDIO ONLINE TODAY!

Purchasing Stylus Studio from our online shop is Easy, Secure and Value Priced!

Buy Stylus Studio Now

Download The World's Best XML IDE!

Accelerate XML development with our award-winning XML IDE - Download a free trial today!

Don't miss another message! Subscribe to this list today.
Email
First Name
Last Name
Company
Subscribe in XML format
RSS 2.0
Atom 0.3
Site Map | Privacy Policy | Terms of Use | Trademarks
Free Stylus Studio XML Training:
W3C Member
Stylus Studio® and DataDirect XQuery ™are products from DataDirect Technologies, is a registered trademark of Progress Software Corporation, in the U.S. and other countries. © 2004-2013 All Rights Reserved.