[XSL-LIST Mailing List Archive Home] [By Thread] [By Date] [Recent Entries] [Reply To This Message]

Re: General algorithm for finding nodes between PIs

Subject: Re: General algorithm for finding nodes between PIs
From: "Michael Kay mike@xxxxxxxxxxxx" <xsl-list-service@xxxxxxxxxxxxxxxxxxxxxx>
Date: Thu, 26 Jan 2017 22:41:04 -0000
Re:  General algorithm for finding nodes between PIs
I think this could be simplified:

> <xsl:template match="*[processing-instruction('Fm')[starts-with(.,
'Condstart')]]">
> 		<xsl:for-each-group select="node()"
group-starting-with="processing-instruction('Fm')[starts-with(.,
'Condstart')]">
> 			<xsl:if test="self::processing-instruction('Fm')[starts-with(.,
'Condstart')]">
> 				<group name="{.}">
> 					<xsl:variable name="pi-end-name" select="replace(., 'Condstart',
'Condend')"/>
> 					<xsl:variable name="end"
select="following-sibling::processing-instruction('Fm')[. =
$pi-end-name][1]">
> 					<xsl:copy-of select="current-group()[. &lt;&lt; $end]"/>
> 				</group>
> 			</xsl:if>
> 		</xsl:for-each-group>
> 		<xsl:apply-templates/>
> 	</xsl:template>

Michael Kay
Saxonica

>
> Like this:
>
> <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
> 	xmlns:xs="http://www.w3.org/2001/XMLSchema"
> 	exclude-result-prefixes="xs"
> 	version="2.0">
>
> 	<xsl:template match="/">
> 		<results>
> 			<xsl:apply-templates/>
> 		</results>
> 	</xsl:template>
>
> 	<xsl:template match="*[processing-instruction('Fm')[starts-with(.,
'Condstart')]]">
> 		<xsl:for-each-group select="node()"
group-starting-with="processing-instruction('Fm')[starts-with(.,
'Condstart')]">
> 			<xsl:if test="self::processing-instruction('Fm')[starts-with(.,
'Condstart')]">
> 				<group name="{.}">
> 					<xsl:variable name="pi-end-name" select="replace(., 'Condstart',
'Condend')"/>
> 					<xsl:for-each-group select="current-group() except ."
group-ending-with="processing-instruction('Fm')[. = $pi-end-name]">
> 						<xsl:if
test="current-group()[last()][self::processing-instruction('Fm')[. =
$pi-end-name]]">
> 							<xsl:copy-of select="current-group()[position() ne last()]"/>
> 						</xsl:if>
> 					</xsl:for-each-group>
> 				</group>
> 			</xsl:if>
> 		</xsl:for-each-group>
> 		<xsl:apply-templates/>
> 	</xsl:template>
>
> 	<xsl:template match="text()"/>
>
> </xsl:stylesheet>

Current Thread

PURCHASE STYLUS STUDIO ONLINE TODAY!

Purchasing Stylus Studio from our online shop is Easy, Secure and Value Priced!

Buy Stylus Studio Now

Download The World's Best XML IDE!

Accelerate XML development with our award-winning XML IDE - Download a free trial today!

Don't miss another message! Subscribe to this list today.
Email
First Name
Last Name
Company
Subscribe in XML format
RSS 2.0
Atom 0.3
Site Map | Privacy Policy | Terms of Use | Trademarks
Free Stylus Studio XML Training:
W3C Member
Stylus Studio® and DataDirect XQuery ™are products from DataDirect Technologies, is a registered trademark of Progress Software Corporation, in the U.S. and other countries. © 2004-2013 All Rights Reserved.