Re: Output sorted XHTML table for a subset of elements

Play the video

Subject: Re: Output sorted XHTML table for a subset of elements
From: Martin Honnen <Martin.Honnen@xxxxxx>
Date: Sun, 25 May 2008 12:53:57 +0200

Steven Davies wrote:

I know my sample data was a bit small but there are a lot more nodes in
my actual data set. Here's an attempt at a better example:

<users>
  <user name="alf"><lines>7</lines></user>
  <user name="bert"><lines>78</lines></user>
  <user name="charlie"><lines>731</lines></user>
  <user name="derek"><lines>62</lines></user>
  <user name="edward"><lines>93</lines></user>
  <user name="fred"><lines>823</lines></user>
  <user name="george"><lines>42</lines></user>
  <user name="harry"><lines>28</lines></user>
  <user name="ian"><lines>553</lines></user>
  <user name="joshua"><lines>92</lines></user>
  <user name="kevin"><lines>108</lines></user>
  <user name="luke"><lines>192</lines></user>
</users>

should give the output:

<table>
  <tr>
    <td>fred (823)</td>
    <td>charlie (731)</td>
    <td>ian (553)</td>
    <td>luke (192)</td>
    <td>kevin (108)</td>
  </tr>
  <tr>
    <td>edward (93)</td>
    <td>joshua (92)</td>
    <td>bert (78)</td>
    <td>derek (62)</td>
    <td>george (42)</td>
  </tr>
  <tr>
    <td>harry (28)</td>
  </tr>
</table>

Here is an XSLT 1.0 stylesheet making use of exslt:node-set:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:exsl="http://exslt.org/common"
  exclude-result-prefixes="exsl"
  version="1.0">

<xsl:output method="html" indent="yes"/>

<xsl:param name="cols" select="5"/>

<xsl:param name="min-lines" select="25"/>

  <xsl:template match="/">
    <html>
      <head>
        <title>Example</title>
      </head>
      <body>
        <xsl:apply-templates select="users"/>
      </body>
    </html>
  </xsl:template>

<xsl:template match="users"> <xsl:variable name="sorted-users-rtf"> <data> <xsl:for-each select="user[lines > $min-lines]"> <xsl:sort select="lines" data-type="number" order="descending"/> <xsl:copy-of select="."/> </xsl:for-each> </data> </xsl:variable> <xsl:variable name="sorted-users" select="exsl:node-set($sorted-users-rtf)/data/user"/> <table> <tbody> <xsl:apply-templates select="$sorted-users[position() mod $cols = 1]" mode="row"/> </tbody> </table> </xsl:template>

<xsl:template match="user" mode="row"> <tr> <xsl:apply-templates select=". | following-sibling::user[position() < $cols]" mode="cell"/> </tr> </xsl:template>

  <xsl:template match="user" mode="cell">
    <td>
      <xsl:value-of select="concat(@name, ' (', lines, ')')"/>
    </td>
  </xsl:template>

</xsl:stylesheet>

I think libXSLT supports exsl:node-set.

--

	Martin Honnen
	http://JavaScript.FAQTs.com/

Current Thread

Output sorted XHTML table for a subset of elements
- Steven Davies - 24 May 2008 14:46:18 -0000
  - Erik Vullings - 25 May 2008 07:45:08 -0000
    - Steven Davies - 25 May 2008 10:33:59 -0000
      - Martin Honnen - 25 May 2008 10:54:22 -0000 <=
      - Erik Vullings - 25 May 2008 22:16:57 -0000
      - Message not available
      - Wendell Piez - 27 May 2008 15:18:18 -0000
      - Wendell Piez - 27 May 2008 15:18:38 -0000
      - Message not available
      - Steven Davies - 27 May 2008 17:26:31 -0000

<- Previous	Index	Next ->
Re: Output sorted XHTML table, Steven Davies	Thread	Re: Output sorted XHTML table, Erik Vullings
Re: Output sorted XHTML table, Steven Davies	Date	unfold one element to several, mixhere
	Month

PURCHASE STYLUS STUDIO ONLINE TODAY!

Purchasing Stylus Studio from our online shop is Easy, Secure and Value Priced!

Download The World's Best XML IDE!

Accelerate XML development with our award-winning XML IDE - Download a free trial today!

Subscribe in XML format

RSS 2.0
Atom 0.3

XML Editor - Download a 15 Day Free Trial Now >

See What's New in Stylus Studio >

Buy Stylus Studio - XML Editor - Now >