[XSL-LIST Mailing List Archive Home] [By Thread] [By Date] [Recent Entries] [Reply To This Message]

Re: Recursive wrapping

Subject: Re: Recursive wrapping
From: "Mukul Gandhi" <gandhi.mukul@xxxxxxxxx>
Date: Thu, 13 Jul 2006 21:46:19 +0530
Re:  Recursive wrapping
Hi Houman,
  This is an example of positional grouping.

Following is one solution to this problem:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

<xsl:output method="xml" indent="yes" />

 <xsl:template match="/root">
   <root>
     <xsl:for-each select="*">
       <xsl:choose>
         <xsl:when test="not(self::Attribute)">
           <xsl:copy-of select="." />
         </xsl:when>
         <xsl:when test="not(preceding-sibling::*[1]/self::Attribute)">
           <OtherAttributes>
              <xsl:copy-of select="." />
              <xsl:call-template name="MakeGroup">
                <xsl:with-param name="nodeset"
select="following-sibling::*" />
              </xsl:call-template>
           </OtherAttributes>
         </xsl:when>
       </xsl:choose>
     </xsl:for-each>
   </root>
 </xsl:template>

 <xsl:template name="MakeGroup">
   <xsl:param name="nodeset" />

   <xsl:if test="$nodeset[1]/self::Attribute">
     <xsl:copy-of select="$nodeset[1]" />
     <xsl:call-template name="MakeGroup">
       <xsl:with-param name="nodeset" select="$nodeset[position() &gt; 1]" />
     </xsl:call-template>
   </xsl:if>
 </xsl:template>

</xsl:stylesheet>

For e.g., when the above stylesheet is applied to XML:

<root>
 <a>1</a>
 <b>2</b>
 <Attribute>
   <Name>xx</Name>
   <Value>xx</Value>
 </Attribute>
 <Attribute>
   <Name>yy </Name>
   <Value>yy</Value>
 </Attribute>
 <c>3</c>
</root>

The following output is produced:

<?xml version="1.0" encoding="UTF-8"?>
<root>
  <a>1</a>
  <b>2</b>
  <OtherAttributes>
     <Attribute>
        <Name>xx</Name>
        <Value>xx</Value>
     </Attribute>
     <Attribute>
        <Name>yy </Name>
        <Value>yy</Value>
     </Attribute>
  </OtherAttributes>
  <c>3</c>
</root>

Regards,
Mukul

On 7/13/06, Khorasani, Houman <Houman.Khorasani@xxxxxxxxxxxx> wrote:
Hi,

I have a problem, which should be quite straight forward but I can't
find the solution.


XML:


<a>1</a>
<b>2</b>
<Attribute>
       <Name>xx</Name>
       <Value>xx</Value>
</Attribute>
<Attribute>
       <Name>yy </Name>
       <Value>yy</Value>
</Attribute>
...
<c>3</c>



Would like to generate:
<a>1</a>
<b>2</b>
<OtherAttributes>
       <Attribute>
               <Name>xx</Name>
               <Value>xx</Value>
       </Attribute>
       <Attribute>
               <Name>yy </Name>
               <Value>yy</Value>
       </Attribute>
       ...
</OtherAttributes>
<c>3</c>

There could be 0 to n attribute elements and I would like to wrap them
between an OtherAttributes.

I have tried to solve it by recursive templates, but somehow I don't get
there.  Any suggestions?

Many thanks
Houman

Current Thread

PURCHASE STYLUS STUDIO ONLINE TODAY!

Purchasing Stylus Studio from our online shop is Easy, Secure and Value Priced!

Buy Stylus Studio Now

Download The World's Best XML IDE!

Accelerate XML development with our award-winning XML IDE - Download a free trial today!

Don't miss another message! Subscribe to this list today.
Email
First Name
Last Name
Company
Subscribe in XML format
RSS 2.0
Atom 0.3
Site Map | Privacy Policy | Terms of Use | Trademarks
Free Stylus Studio XML Training:
W3C Member
Stylus Studio® and DataDirect XQuery ™are products from DataDirect Technologies, is a registered trademark of Progress Software Corporation, in the U.S. and other countries. © 2004-2013 All Rights Reserved.