Re: Counting nodes processed

[JAY SCHERER]

> I've got a need to limit the amount of ouput generated in a translation.
Assume the following xml
>
> <category value="category1">
>   <topic value="topic1"/>
>   <topic value="topic2"/>
>   <topic value="topic3"/>
> </category>
> <category value="category2">
>   <topic value="topic1"/>
>   <topic value="topic2"/>
>   <topic value="topic3"/>
> </category>
>
> How would I limit my total number of topics output to say 4 topics?  This
is straight forward in code, but not sure how to do it xsl?  Basically the
output would be topic1,2 and 3 from category1 and topic 1 from category 2
>

cutlass <cutlass@xxxxxxxxxxx> suggested using position(), but that may not
work because position() depends on the context of the current node, which
can vary depending on how you refer to it.  It is easy to get unexpected
results using position().

Here is a different approach.  You first select just those topics you want
to use.  If you want to output just four topics, you can select those topics
where the count of  all preceding topic elements  is less than 4.  This will
work unambiguously.

Here's what it might look like:

====================================
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:variable name='allowed-elements'
select='/doc/category/topic[count(preceding::topic)&lt;4]'/>

<xsl:template match="/">
<results>
 <xsl:apply-templates select='$allowed-elements'/>
</results>
</xsl:template>

<xsl:template match='topic'>
 <xsl:value-of select='ancestor::category[1]/@value'/>-- <xsl:value-of
select='@value'/><br/>
</xsl:template>

</xsl:stylesheet>
================================

Here is the result (the <br/> is there only to give an artificial line feed
for visual formatting in Internet Explorer):

===============================
<results>
  category1-- topic1
  <br />
  category1-- topic2
  <br />
  category1-- topic3
  <br />
  category2-- topic1
  <br />
  </results>
==================================

Cheers,

Tom P


 XSL-List info and archive:  http://www.mulberrytech.com/xsl/xsl-list