[XSL-LIST Mailing List Archive Home] [By Thread] [By Date] [Recent Entries] [Reply To This Message]

Re: Grouping lists from flat to nested

Subject: Re: Grouping lists from flat to nested
From: Martin Honnen <Martin.Honnen@xxxxxx>
Date: Mon, 31 Jan 2011 15:05:56 +0100
Re:  Grouping lists from flat to nested
Stefanie Haupt wrote:

I've chunked my grouping attempts and indeed there is another grouping
happening later (dividing the headers with the following elements into
nested sections) but here I only wanted to group the lists properly. I
found it rather confusing to group too much at a time. To answer your
question: I would not want to nest the p elements. I've just added the
level attribute here to prevent these elements from being nested
within the lists (because that's what happening if i remove the
attribute).

Based on your explanation and the required result I think you should rather use group-adjacent than group-starting-with.
Here is an example stylesheet:


<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:mf="http://example.com/mf"
  version="2.0"
  exclude-result-prefixes="xs mf">

  <xsl:strip-space elements="*"/>
  <xsl:output indent="yes"/>

<xsl:function name="mf:group" as="node()*">
<xsl:param name="nodes" as="node()*"/>
<xsl:param name="level" as="xs:integer"/>
<xsl:if test="$nodes">
<list type="ul">
<xsl:for-each-group select="$nodes" group-adjacent="boolean(self::*[@level = $level])">
<xsl:choose>
<xsl:when test="current-grouping-key()">
<xsl:apply-templates select="current-group()"/>
</xsl:when>
<xsl:otherwise>
<xsl:sequence select="mf:group(current-group(), $level + 1)"/>
</xsl:otherwise>
</xsl:choose>
</xsl:for-each-group>
</list>
</xsl:if>
</xsl:function>


  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@*, node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="item[@level]">
    <item>
      <xsl:apply-templates/>
    </item>
  </xsl:template>

  <xsl:template match="test">
    <xsl:copy>
      <xsl:for-each-group select="*" group-adjacent="boolean(self::item)">
        <xsl:choose>
          <xsl:when test="current-grouping-key()">
            <xsl:sequence select="mf:group(current-group(), 0)"/>
          </xsl:when>
          <xsl:otherwise>
            <xsl:apply-templates select="current-group()"/>
          </xsl:otherwise>
        </xsl:choose>
      </xsl:for-each-group>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

When applied to the input

<test>
<p level="0">Der als Filmregisseur  <hi rend="bo">Alan Smithee</hi>
ist ein.. </p>
<p level="0">Das Pseudonym.. .</p>
<p level="0">Der Regisseur...</p>
<head2 level="0">Wissenswertes</head2>
<item level="0" type="ul">Alternative Schreibweisen..</item>
<item level="0" type="ul">Eine alternative Theorie...</item>
<item level="0" type="ul">Zu den ... </item>
<item level="1" type="ul">Don  </item>
<item level="1" type="ul">David Lynch </item>
<item level="1" type="ul">Chris Christensen </item>
<item level="1" type="ul">Stuart Rosenberg</item>
<item level="1" type="ul">Richard C. Sarafian</item>
<item level="1" type="ul">Dennis Hopper  </item>
<item level="2" type="ul"> level 3 ulitem</item>
<item level="1" type="ul">Arthur Hiller (fC<r ), </item>
<item level="1" type="ul">Rick Rosenthal (Birds II) und </item>
<item level="1" type="ul">Kevin Yagher </item>
<item level="0" type="ul">Zu den Drehbuchautoren </item>
<item level="1" type="ul">Sam Raimi und Ivan Raimi </item>
<head2 level="0">Weblinks</head2>
</test>


Saxon 9.3 outputs


<test>
   <p level="0">Der als Filmregisseur  <hi rend="bo">Alan Smithee</hi>
ist ein.. </p>
   <p level="0">Das Pseudonym.. .</p>
   <p level="0">Der Regisseur...</p>
   <head2 level="0">Wissenswertes</head2>
   <list type="ul">
      <item>Alternative Schreibweisen..</item>
      <item>Eine alternative Theorie...</item>
      <item>Zu den ... </item>
      <list type="ul">
         <item>Don  </item>
         <item>David Lynch </item>
         <item>Chris Christensen </item>
         <item>Stuart Rosenberg</item>
         <item>Richard C. Sarafian</item>
         <item>Dennis Hopper  </item>
         <list type="ul">
            <item> level 3 ulitem</item>
         </list>
         <item>Arthur Hiller (fbbr ), </item>
         <item>Rick Rosenthal (Birds II) und </item>
         <item>Kevin Yagher </item>
      </list>
      <item>Zu den Drehbuchautoren </item>
      <list type="ul">
         <item>Sam Raimi und Ivan Raimi </item>
      </list>
   </list>
   <head2 level="0">Weblinks</head2>
</test>




--


	Martin Honnen
	http://msmvps.com/blogs/martin_honnen/

Current Thread

PURCHASE STYLUS STUDIO ONLINE TODAY!

Purchasing Stylus Studio from our online shop is Easy, Secure and Value Priced!

Buy Stylus Studio Now

Download The World's Best XML IDE!

Accelerate XML development with our award-winning XML IDE - Download a free trial today!

Don't miss another message! Subscribe to this list today.
Email
First Name
Last Name
Company
Subscribe in XML format
RSS 2.0
Atom 0.3
Site Map | Privacy Policy | Terms of Use | Trademarks
Free Stylus Studio XML Training:
W3C Member
Stylus Studio® and DataDirect XQuery ™are products from DataDirect Technologies, is a registered trademark of Progress Software Corporation, in the U.S. and other countries. © 2004-2013 All Rights Reserved.