Re: Get value from update.xml and stored in source.xm

Using xslt 1.0 I have to extract the value of <test2> which is in <test1
id="0000001"> of update.xml and put it in <test2> which is in <test1
id="0000001"> of source.xml.

This should updates the <test2> of source.xml without any other changes.

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:variable name="update" select="document('update.xml')"/>
<xsl:key name="id" match="*" use="@id"/>

<xsl:template match="*[@id]">
	<xsl:variable name="id" select="@id"/>
	<xsl:copy>
		<xsl:apply-templates select="@*" />
		<xsl:for-each select="$update">
			<xsl:copy-of select="key('id',$id)/*"/>
		</xsl:for-each>
	</xsl:copy>
</xsl:template>

<xsl:template match="node()|@*">
	<xsl:copy>
		<xsl:apply-templates select="node()|@*" />
	</xsl:copy>
</xsl:template>

--
Joris Gillis (http://users.telenet.be/root-jg/me.html)
Deserta faciunt et innovationem appelant