Re: WordML to XML

Play the video

Subject: Re: WordML to XML
From: "Joris Gillis" <roac@xxxxxxxxxx>
Date: Sat, 12 Feb 2005 11:18:52 +0100

Tempore 03:14:57, die 02/12/2005 AD, hinc in xsl-list@xxxxxxxxxxxxxxxxxxxxxx scripsit Vasu Nanjangud <vasdeep@xxxxxxxxx>:

Joris, et al...

My requirement is specifically to convert wordML to
xml. i.e. strip off the "wordML" specific tags, but
retain the "formatting instructions".

When you apply this template to your WordML doc:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0" xmlns:w="http://schemas.microsoft.com/office/word/2003/wordml" exclude-result-prefixes="w"> <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="w:wordDocument">
	<vasuarticletag>
		<xsl:apply-templates select=".//w:body"/>
	</vasuarticletag>
</xsl:template>

<xsl:template match="w:r ">
	<xsl:apply-templates select="(w:rPr|w:t)[1]"  mode="styling"/>
</xsl:template>

<xsl:template match="w:rPr"  mode="styling">
	<xsl:apply-templates select="*[1]" mode="styling"/>
</xsl:template>

<xsl:template match="w:u|w:b|w:i" priority="5" mode="styling"> <xsl:element name="{local-name()}"> <xsl:apply-templates select="(following-sibling::*|../../w:t)[1]" mode="styling"/> </xsl:element> </xsl:template>

<xsl:template match="w:rPr/*" mode="styling"> <xsl:apply-templates select="(following-sibling::*|../../w:t)[1]" mode="styling"/> </xsl:template>

<xsl:template match="w:t" mode="styling"><xsl:value-of select="."/></xsl:template>

</xsl:stylesheet>

you will get this output:

<vasuarticletag>
<b>
   <i>
     <u>
         I have bold, italics and underscore
     </u>
   </i>
</b>
</vasuarticletag>

(I added modes, so the algorithm will not interfere with other templates you might be using.)

So, I need help in writing an xslt which will
1. traverse through every "w:r" block.

done.

2. Look for "w:rPr" tags with "w:i", "w:b" , "w:u"
children.

possible, but not necessary.

3. If they exist, output <i>, <b>, <u> tags, then
output the contents of the corresponding "w:t" block
and then close the <i>, <b>, <u> tags.

This is not the way XSLT works. In XSLT you construct elements, which are added to the result tree. When the XSLT processing is done, a serializer outputs these elements as tags. In other words, you cannot "open a tag" nor "close a tag" in XSLT. (unless your messing with it as if it was character data, but don't do that)

While step 3 of your the algorithm, can't be used in XSLT. The templates in my stylesheet will give output exactly as if they were following step 3.


regards,
--
Joris Gillis (http://www.ticalc.org/cgi-bin/acct-view.cgi?userid=38041)
Gaudiam omnibus traderat W3C, nec vana fides

Current Thread
Re: WordML to XML Vasu Nanjangud - 12 Feb 2005 05:33:15 -0000 Joris Gillis - 12 Feb 2005 10:19:11 -0000 <= Touchtel - 12 Feb 2005 10:47:17 -0000 <Possible follow-ups> Vasu Nanjangud - 13 Feb 2005 07:49:05 -0000 Joris Gillis - 13 Feb 2005 09:55:06 -0000 Vasu Nanjangud - 16 Feb 2005 06:27:33 -0000

<- Previous	Index	Next ->
Re: WordML to XML, Vasu Nanjangud	Thread	RE: WordML to XML, Touchtel
Re: Summing grouped elements, Mukul Gandhi	Date	Re: Understanding Identity Tr, Joris Gillis
	Month

PURCHASE STYLUS STUDIO ONLINE TODAY!

Purchasing Stylus Studio from our online shop is Easy, Secure and Value Priced!

Download The World's Best XML IDE!

Accelerate XML development with our award-winning XML IDE - Download a free trial today!

Subscribe in XML format

RSS 2.0
Atom 0.3

XML Editor - Download a 15 Day Free Trial Now >

See What's New in Stylus Studio >

Buy Stylus Studio - XML Editor - Now >