RE: Re: accumulate a variable...is it possible?

Here's a solution using a recursive template. The main thing to define when
writing a recursive template is a proper stop condition that always will be
met. Often times the recursive template has two parameters: one to contain
intermediate states of something that eventually will lead to the stop
condition, and one for intermediate states of the desired end result. See
the comments in the stylesheet templates below, that should make things
clearer.

XSL templates:
==============

<xsl:template match="num">
	<xsl:text>
	 num=</xsl:text>
	<xsl:value-of select="."/> 
	<xsl:text>  accumulated=</xsl:text>
	<!-- to calculate sum of current and previous sibling nodes, define 
 		nodeset containing those previous nodes and call 
		recursive template -->
	<xsl:variable name="nodeset" select="preceding-sibling::num"/>
	<xsl:call-template name="accumulate">
		<!-- input params for named template:
			sum = the value of the current node 
			nodeset = nodeset containing the previous sibling
nodes -->
		<xsl:with-param name="sum" select="."/>
		<xsl:with-param name="nodeset" select="$nodeset"/>
	</xsl:call-template>
</xsl:template>

<!-- recursive template -->
<xsl:template name="accumulate">
	<xsl:param name="sum"/>
	<xsl:param name="nodeset"/>
	<xsl:choose>
		<!-- define appropriate stop condition -->
		<xsl:when test="$nodeset">
			<!-- stop condition is not yet met, call self with
new values 
                        for sum and nodeset params:
				sum = previous sum + value of first node in
nodeset
				nodeset = previous nodeset minus the first
node (this 
				ensures that eventually the stop condition
will be met) -->
			<xsl:call-template name="accumulate">
				<xsl:with-param name="sum" 
	
select="number($nodeset[position()=1]) + $sum"/>
				<xsl:with-param name="nodeset" 
					select="$nodeset[position()!=1]"/>
			</xsl:call-template>
		</xsl:when>
		<xsl:otherwise>
			<!-- stop condition is met, so output the result -->
			<xsl:value-of select="$sum"/>
		</xsl:otherwise>
	</xsl:choose>
</xsl:template>

XML Input:
==========

<numbers>
	<num>3</num>
	<num>7</num>
	<num>11</num>
	<num>6</num>
	<num>3</num>
</numbers>

Output:
=======

	 num=3  accumulated=3
	 num=7  accumulated=10
	 num=11  accumulated=21
	 num=6  accumulated=27
	 num=3  accumulated=30

Edward

> -----Original Message-----
> From: Dimitre Novatchev [mailto:dnovatchev@xxxxxxxxx]
> Sent: Wednesday, October 09, 2002 12:44 PM
> To: xsl-list@xxxxxxxxxxxxxxxxxxxxxx
> Subject:  Re: accumulate a variable...is it possible?
> 
> 
> 
> --- G. Ken Holman wrote:
>  
> > At 2002-10-09 12:49 -0500, Carter, Will wrote:
> > >I am trying to accumulate a variable 
> > 
> > You don't say why so it is difficult to advise how to fix 
> the problem
> > you 
> > are trying to solve using a variable.
> > 
> > To mimic the results you want, an example is below.
> > 
> > I hope this helps.
> > 
> > ............ Ken
> > 
> > T:\ftemp>type carter.xml
> > <numbers>
> >    <num>3</num>
> >    <num>7</num>
> >    <num>11</num>
> >    <num>6</num>
> >    <num>3</num>
> > </numbers>
> > 
> > T:\ftemp>type carter.xsl
> > <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
> >                  version="1.0">
> > 
> > <xsl:output method="text"/>
> > 
> > <xsl:template match="num">
> >    <xsl:text/>num=<xsl:value-of select="."/>
> >    <xsl:text> accumulated=</xsl:text>
> >    <xsl:value-of select="sum(. | preceding-sibling::num)"/>
> > </xsl:template>
> > 
> > </xsl:stylesheet>
> > 
> > T:\ftemp>xt carter.xml carter.xsl
> > 
> >    num=3 accumulated=3
> >    num=7 accumulated=10
> >    num=11 accumulated=21
> >    num=6 accumulated=27
> >    num=3 accumulated=30
> > 
> > T:\ftemp>
> > 
> > 
> > --
> > G. Ken Holman              
> 
> While this seems an easy way to scan the computation, its 
> complexity is
> O(N^2).
> 
> A more efficient linear solution is available either by using the
> scanl/scanl1 templates of FXSL or by writing from scratch a recursive
> named template.
> 
> 
> 
> =====
> Cheers,
> 
> Dimitre Novatchev.
> http://fxsl.sourceforge.net/ -- the home of FXSL
> 
> __________________________________________________
> Do you Yahoo!?
> Faith Hill - Exclusive Performances, Videos & More
> http://faith.yahoo.com
> 
>  XSL-List info and archive:  http://www.mulberrytech.com/xsl/xsl-list
> 

 XSL-List info and archive:  http://www.mulberrytech.com/xsl/xsl-list