Re: Filtering Numeric Output with Changing Parameter

<xsl:template match="root">
    <root>
        <xsl:apply-templates select="stock[1]"/>
    </root>
</xsl:template>

<xsl:template match="stock">
    <xsl:variable name="threshold" select="1"/>
    <xsl:copy-of select="."/>
    <xsl:apply-templates select="following-sibling::stock
            [price >= current()/price + $threshold
          or price &lt;= current()/price - $threshold][1]"/>
</xsl:template>

I'd like to take a pile of numeric data and filter it down to a smaller
pile by selecting for output only values that change by more than a
threshold amount from the beginning value.  If a value gets selected for

output, then the next output value would have to be different from it by

more than the threshold.  For example, say I have a pile of stock price
data and I want to plot only values that change by more than 1.00.  If
the first value is 27.50, then I want to look through the data and
ignore it until I find a price >= 28.50 or <= 26.50.  If I find a price
of 28.50, then I want to continue my search, but now I am looking for
prices >= 29.50 or <= 27.50.

So given:

<stock>
   <time>0.0</time>
   <price>27.50</price>
</stock>
<stock>
   <time>1.0</time>
   <price>27.75</price>
</stock>
<stock>
   <time>3.0</time>
   <price>27.20</price>
</stock>
<stock>
   <time>4.0</time>
   <price>28.50</price>
</stock>
<stock>
   <time>5.0</time>
   <price>28.25</price>
</stock>
<stock>
   <time>6.0</time>
   <price>27.75</price>
</stock>
<stock>
   <time>7.0</time>
   <price>27.80</price>
</stock>
<stock>
   <time>8.0</time>
   <price>25.50</price>
</stock>

I want:

<stock>
   <time>0.0</time>
   <price>27.50</price>
</stock>
<stock>
   <time>4.0</time>
   <price>28.50</price>
</stock>
<stock>
   <time>8.0</time>
   <price>25.50</price>
</stock>

I understand that I cannot use a for-each loop because the value of my
comparison "variables" needs to be variable.  I also understand that I
need to use recursion to do it.  However, I struggle mightily with
procedural programming, so functional programming and recursion chew me
up and spit me out.

Any guidance would be appreciated.  An actual named template to get this
job done would be even more wondeful!

TIA,

Tim Lewis