RE: select only some elements and attributes

Try this:

<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:template match="title | price | weight | company | phone | @*">
    <xsl:copy-of select="."/> <!--performs a "deep" copy" -->
  </xsl:template>

  <xsl:template match="product | vendor">
    <xsl:copy>  <!-- performs a "shallow" copy -->
      <xsl:apply-templates select="* | @*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="*"/>
  <!-- for all other elements, do nothing (this overrides the built-in
template rule for elements) -->

</xsl:stylesheet>

Hope this helps,

Evan Lenz
XYZFind Corp.

-----Original Message-----
From: owner-xsl-list@xxxxxxxxxxxxxxxxxxxxxx
[mailto:owner-xsl-list@xxxxxxxxxxxxxxxxxxxxxx]On Behalf Of Meili Zhong
Sent: Wednesday, February 14, 2001 4:55 PM
To: XSL-List@xxxxxxxxxxxxxxxxxxxxxx
Subject:  select only some elements and attributes


Hi, What's the best way to only select some elements and attributes using
xslt? For example, the xml source looks like:

<product sku="123465-45">
   <title>Mutton and Rice Dog Food</title>
   <description sku="2345-67">Everything needed for your pet's
health</description>
   <price>25.99</price>
   <available_date>2000-12-25</available_date>
   <size>large</size>
   <weight>40lbs</weight>
   <vendor>
      <company>Nutro Max</company>
      <street>15 Industrial Blvd</street>
      <city>Reno</city>
      <state>NV</state>
      <zip>56381</zip>
      <phone>583 233-4598</phone>
   </vendor>
</product>

The output I want should be like:

<product sku="123465-45">
   <title>Mutton and Rice Dog Food</title>
   <price>25.99</price>
   <weight>40lbs</weight>
   <vendor>
      <company>Nutro Max</company>
      <phone>583 233-4598</phone>
   </vendor>
</product>

Thank you very much!

Meili Zhong


 XSL-List info and archive:  http://www.mulberrytech.com/xsl/xsl-list


 XSL-List info and archive:  http://www.mulberrytech.com/xsl/xsl-list