XML Editor
Sign up for a WebBoard account Sign Up Keyword Search Search More Options... Options
Chat Rooms Chat Help Help News News Log in to WebBoard Log in Not Logged in
Show tree view Topic
Topic Page 1 2 3 4 5 6 7 8 9 Go to previous topicPrev TopicGo to next topicNext Topic
Postnext
saffrons saffronsSubject: help me implement the following in xslt
Author: saffrons saffrons
Date: 12 Sep 2005 04:38 AM
This is my requirement,

the input xml will be in this format,

<root>
<name>1</name>
<name>2</name>
<name>3</name>
<name>1</name>
<name>2</name>
<name>1</name>
</root>

The possible values for name are only 1,2 and 3. I should supply an xsl which will be used to transform this xml into another xml in the following format,

<root>
<Loop>
<name>1</name>
<Loop>
<name>2</name>
<Loop>
<name>3</name>
</Loop>
</Loop>
</Loop>
<Loop>
<name>1</name>
<Loop>
<name>2<name>
</Loop>
</Loop>
<Loop>
<name>1</name>
</Loop>
</root>

In the input xml, there will not be a 2 without 1 preceding it. similarly there wont be a 3 without a 2 preceding it. But there could be more than one 2, one after the other. Here's another example,

<root>
<name>1</name>
<name>2</name>
<name>2</name>
</root>

Here the output will be
<root>
<Loop>
<name>1</name>
<Loop>
<name>2</name>
</Loop>
<Loop>
<name>2</name>
</Loop>
</Loop>
</root>

I thought of using the following algorithm to determine when to open a loop element and when to close a loop,

declare variables L1 = no, L2 = no and L3 = no
For each <root> in output xml
{
If (name = 1)
{
If (L3 = yes) then in output xml, close loop "</Loop>"
If (L2 = yes) then in output xml, close loop "</Loop>"
If (L1 = yes) then in output xml, close loop "</Loop>"
Open Loop in output xml "<Loop>"
}
If (name = 2)
{
If (L3 = yes) then in output xml, close loop "</Loop>"
If (L2 = yes) then in output xml, close loop "</Loop>"
Open Loop in output xml "<Loop>"
}
If (name = 3)
{
If (L3 = yes) then in output xml, close loop "</Loop>"
Open Loop in output xml "<Loop>"
}
}

But here, since variable values once assigned cannot be reassigned, I am not able to implement this algo. in xsl. Help me with some other logic that will be able to achieve the same. (all I want here is to do the following, there will be an input xml file where all elements are in the same level. In the output file, I want these elements nested one inside another, based on their values.)

Postnext
(Deleted User) Subject: help me implement the following in xslt
Author: (Deleted User)
Date: 12 Sep 2005 05:56 AM
Hi Saffrons,
this is a possible solution:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/">
<root>
<xsl:apply-templates select="root/name[. = '1']"/>
</root>
</xsl:template>


<xsl:template match="name">
<xsl:variable name="myIndex" select="number(.)"/>
<xsl:variable name="nextIndex" select="number(.)+1"/>
<Loop>
<xsl:copy-of select="."/>
<xsl:apply-templates select="following-sibling::name[1][. = $nextIndex]"/>
</Loop>
<xsl:if test="$myIndex != 1">
<xsl:apply-templates select="following-sibling::name[1][. = $myIndex]"/>
</xsl:if>
</xsl:template>

</xsl:stylesheet>

Hope this helps,
Alberto

Postnext
saffrons saffronsSubject: help me implement the following in xslt
Author: saffrons saffrons
Date: 12 Sep 2005 06:29 AM
hi alberto,
thank you and that worked fine. but is there any other solution in case i have multiple values that might start a specific level loop? eg., not only '1' but values 'one','first','top' and 'high' are all equivalent. Similarly '2','two','second' are equivalent. '3','three','third' are equivalent. the i/p file might be like
<root>
<name>one</name>
<name>2</name>
<name>third</name>
</root>
now the o/p shud be like,
<root>
<Loop>
<name>one</name>
<Loop>
<name>2</name>
<Loop>
<name>third</name>
</Loop>
</Loop>
</Loop>
</root>

-saffrons

Posttop
(Deleted User) Subject: help me implement the following in xslt
Author: (Deleted User)
Date: 12 Sep 2005 08:16 AM
Hi Saffrons,
a more elegant solution could be done using XSLT 2, but this should work too, given the small amount of choices:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/">
<root>
<xsl:apply-templates select="root/name[. = '1' or . = 'first' or . = 'one']"/>
</root>
</xsl:template>


<xsl:template match="name[. = '1' or . = 'first' or . = 'one']">
<Loop>
<xsl:copy-of select="."/>
<xsl:apply-templates select="following-sibling::name[1][. = '2' or . = 'second' or . = 'two']"/>
</Loop>
</xsl:template>

<xsl:template match="name[. = '2' or . = 'second' or . = 'two']">
<Loop>
<xsl:copy-of select="."/>
<xsl:apply-templates select="following-sibling::name[1][. = '3' or . = 'third' or . = 'three']"/>
</Loop>
<xsl:apply-templates select="following-sibling::name[1][. = '2' or . = 'second' or . = 'two']"/>
</xsl:template>

<xsl:template match="name[. = '3' or . = 'third' or . = 'three']">
<Loop>
<xsl:copy-of select="."/>
</Loop>
<xsl:apply-templates select="following-sibling::name[1][. = '3' or . = 'third' or . = 'three']"/>
</xsl:template>

</xsl:stylesheet>

Hope this helps,
Alberto

 
Topic Page 1 2 3 4 5 6 7 8 9 Go to previous topicPrev TopicGo to next topicNext Topic
Download A Free Trial of Stylus Studio 6 XML Professional Edition Today! Powered by Stylus Studio, the world's leading XML IDE for XML, XSLT, XQuery, XML Schema, DTD, XPath, WSDL, XHTML, SQL/XML, and XML Mapping!  
go

Log In Options

Site Map | Privacy Policy | Terms of Use | Trademarks
Stylus Scoop XML Newsletter:
W3C Member
Stylus Studio® and DataDirect XQuery ™are from DataDirect Technologies, is a registered trademark of Progress Software Corporation, in the U.S. and other countries. © 2004-2016 All Rights Reserved.