declare function local:getRelated20s($item) {
    let $nextItem := $item/following-sibling::*[local-name()!="record_20" and local-name()!="record_30"][1]
    for $related in $item/following-sibling::*[local-name()="record_20"]
    where if($nextItem) then $related << $nextItem else true()
    return $related
};

declare function local:getRelated30s($item) {
    let $nextItem := $item/following-sibling::*[local-name()!="record_30"][1]
    for $related in $item/following-sibling::*[local-name()="record_30"]
    where if($nextItem) then $related << $nextItem else true()
    return $related
};

<DataSets>
	{
	for $record_10 in doc('converter:file:///c:/test.conv?http://www.stylusstudio.com/SSDN/upload/SampleInput.TXT')/root/record_10
	return
	<DataSet>
		<CustomerId>
			{$record_10/customer_id/text()}
		</CustomerId>
		<CustomerName>
			{$record_10/lastname/text()}
		</CustomerName>
		<CustomerFirstName>
			{$record_10/firstname/text()}
		</CustomerFirstName>
		<Accounts>
			{
			for $record_20 in local:getRelated20s($record_10)
			return
			<Account>
				<AccountId>
					{$record_20/account_id/text()}
				</AccountId>
				<Transactions> {
					for $record_30 in local:getRelated30s($record_20)
					return
						<Transaction>
							<Label>{$record_30/label/text()}</Label>
							<Value>{$record_30/value/text()}</Value>
						</Transaction>
				} </Transactions>
			</Account>
			}
		</Accounts>
	</DataSet>
	}
</DataSets>