SSDN - problem with sorting table contents based on randomly selected header

XML Editor

Sign Up

Search

Options

Chat

Help

News

Log in

Not Logged in

Topic

Topic Page 1 2 3 4 5 6 7 8 9

chandra mouli

Subject: problem with sorting table contents based on randomly selected header
Author: chandra mouli
Date: 27 Sep 2004 05:22 AM

hi all,

this is chandramouli.
this is my urgent requirement.

i have the problem with sorting the table contents based on
dynamically selected header.

can u plz solve my problem.

i have written my xml code like this

<?xml version="1.0" encoding="UTF-8" ?>
<userdetails>
<user>
<name>mouli</name>
<id>t001</id>
<designation>trainee</designation>
</user>
<user>
<name>naveen</name>
<id>t002</id>
<designation>student</designation>
</user>
<user>
<name>chandra</name>
<id>t004</id>
<designation>software engineer</designation>
</user>
<user>
<name>haritha</name>
<id>t004</id>
<designation>student</designation>
</user>
</userdetails>

the xsl code that i have written to display the above xml content in
table format. In that code itself i have written the code to dynamically
sort the table data. but it is not properly working.
when i use the static variable instead of that dynamic variable. it is
working nice.

xsl code that i have written is .

<?xml version='1.0' encoding='UTF-8'?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="html" />
<xsl:param name="Sor"/>
<xsl:param name="Page"/>

<xsl:template match="/">
<table border="1">
<xsl:call-template name="header"/>
<xsl:apply-templates select="*/*">
<xsl:sort select="*[$Sor]"/>
</xsl:apply-templates>
</table>
</xsl:template>


<xsl:template name="header">
<tr>
<xsl:for-each select="*/*[1]/*">
<th>
<A href="{$Page} ?Sor={position()}">
<xsl:value-of select="local-name(.)" />
</A>
</th>
</xsl:for-each>
</tr>
</xsl:template>



<xsl:template name="content" match="*/*">
<tr>
<xsl:for-each select="*">
<td><xsl:value-of select="." /></td>
</xsl:for-each>
</tr>
</xsl:template>

</xsl:stylesheet>

inaddition to this i have written some code in jsp to integrate both xml
and xsl code..

jsp code that i have written is

<html>
<body>
<script type="text/javascript">// Load XML
var xml = new ActiveXObject("Microsoft.XMLDOM")
xml.async = true
xml.load("data.xml")

// Load XSL
var xsl = new ActiveXObject("Microsoft.XMLDOM")
xsl.async = true
xsl.load("xslsort.xsl")

// Transform
document.write(xml.transformNode(xsl))
</script>

</body>
</html>

any one of u plz suggest me the solution.

of my knowledge every thing is fine but the page not getting refreshed.
if it is the case plz any one of you suggest me the solution.

this is my urgent requirement. plz suggest me the solution.

thanks in advance...

thanks and regards,
chandramouli.p

Ivan Pedruzzi

Subject: problem with sorting table contents based on randomly selected header
Author: Ivan Pedruzzi
Date: 29 Sep 2004 06:33 PM

Hi Chandra,

Here is one of the possible approaches to implment what you are looking for

1) This a simple XSLT that produce the HTML table

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="html"/>
<xsl:param name="sortby" select="'name'"/>

<xsl:template match="/">
<div id="divID">
<table border="1">
<xsl:call-template name="header"/>
<xsl:apply-templates select="userdetails/user">
<xsl:sort select="*[name()=$sortby]" data-type="text"/>
</xsl:apply-templates>
</table>
</div>
</xsl:template>

<xsl:template name="header">
<tr>
<xsl:for-each select="*/*[1]/*">
<th>
<a href="sorttable.asp?sortby={local-name(.)}">
<xsl:value-of select="local-name(.)"/>
</a>
</th>
</xsl:for-each>
</tr>
</xsl:template>

<xsl:template match="user">
<tr>
<td><xsl:value-of select="name"/></td>
<td><xsl:value-of select="id"/></td>
<td><xsl:value-of select="designation"/></td>
</tr>
</xsl:template>
</xsl:stylesheet>

2) This is the Active Server Page that run the stylesheet.
The result is a HTML page with a clickable header to do sorting

<%@ LANGUAGE = jscript %>
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=windows-1252">
<title>Sortable Table</title>
</head>
<body>
<%
var sortby = Request.QueryString("sortby");
var xmlpath = Server.mappath("sorttable.xml");
var xslpath = Server.mappath("sorttable.xsl");

var xslt = new ActiveXObject("Msxml2.XSLTemplate.4.0");
var xsldoc = new ActiveXObject("Msxml2.FreeThreadedDOMDocument.4.0");
var xmldoc = new ActiveXObject("Msxml2.DOMDocument.4.0");
var xslproc;

xsldoc.async = false;
xsldoc.load(xslpath);

if (xsldoc.parseError.errorCode != 0) {
var myErr = xsldoc.parseError;
Response.write(myErr.reason);
} else {
xslt.stylesheet = xsldoc;
xmldoc.async = false;
xmldoc.load(xmlpath);
if (xmldoc.parseError.errorCode != 0) {
var myErr = xmldoc.parseError;
Response.write(myErr.reason);
} else {
xslproc = xslt.createProcessor();
xslproc.input = xmldoc;
xslproc.addParameter("sortby", String(sortby));
xslproc.transform();
Response.write(xslproc.output);
}
}
%>
</body>
</html>

For your convenience I also attached the files as zip

Hope this helps
Ivan

Topic Page 1 2 3 4 5 6 7 8 9

Powered by Stylus Studio, the world's leading XML IDE for XML, XSLT, XQuery, XML Schema, DTD, XPath, WSDL, XHTML, SQL/XML, and XML Mapping!

Go to Conference:

Log In Options Username: Password:

Site Map | Privacy Policy | Terms of Use | Trademarks

Stylus Studio® and DataDirect XQuery ™are from DataDirect Technologies, is a registered trademark of Progress Software Corporation, in the U.S. and other countries. © 2004-2016 All Rights Reserved.